In a Word 2010 report, various reviewers have worked on their individual sections so track changes shows their individual names.

Now the client wants no individual name but company initials instead.

Can I somehow make that change from my computer? If they open the doc on their computer and make the change individually, is there a way to update that information?

Thanks!

• Edited by Susan Muncy 15 hours 59 minutes ago

Is this you want ?

https://support.office.com/en-ca/article/Change-the-author-name-for-review-comments-cdd4b8ac-fbca-438d-a5b5-a99fb1c750e3

You could do that with a macro, such as:

Sub Demo()
Application.ScreenUpdating = False
Dim StrUser As String, StrCompany As String, i As Long, Rng As Range, RngMv As Range, bTrk As Boolean
StrUser = Application.UserName: StrCompany = "My Company"
Application.UserName = StrCompany
With ActiveDocument
  On Error Resume Next
  bTrk = .TrackRevisions
  .TrackRevisions = True
  For i = 1 To .Revisions.Count
    Set Rng = .Revisions(i).Range
    With .Revisions(i)
      If .Author <> StrCompany Then
        If .Type = wdRevisionDelete Then
          .Reject
          Rng.Delete
        End If
        If .Type = wdRevisionInsert Then
          Rng.Copy
          Rng.Collapse wdCollapseEnd
          .Reject
          Rng.Paste
        End If
      End If
    End With
  Next
  For i = .Revisions.Count To 1 Step -1
    Set Rng = .Revisions(i).Range
    With .Revisions(i)
      If .Author <> StrCompany Then
        If .Type = wdRevisionMovedFrom Then
          Set RngMv = .MovedRange
          .Reject
          Rng.Cut
          RngMv.Paste
        End If
      End If
    End With
  Next
  .TrackRevisions = bTrk
End With
Application.UserName = StrUser
Application.ScreenUpdating = True
End Sub

The above macro deals with insertions, deletions and moves. There are numerous other revision types that might also need to be dealt with - I'll leave it to your organization to code for them. Change 'My Company' to whatever name you want to use.